Musicogramas con flash

[Octavi Soler]

En este minitutorial voy a intentar explicar la forma de hacer musicogramas con Flash. Le dedico este tutorial especialmente a Nani, a la que quedé en pasárselo ya hace meses. Más vale tarde que nunca.
El resultado que se trata de conseguir es algo así: Pincha aquí para pantalla completa


Generalmente los alumnos siguen los musicogramas  sobre el papel señalando rítmicamente sobre los  dibujos de corazones u otros simbolos que representen el pulso musical. Así que esta actividad puede ejemplificar lo que han de hacer, y pueden además intentar seguirla señalando en la PDI. Una variante, que podemos ver más adelante, es hacerla aún más interactiva, de forma que si el alumno no la sigue 'a tempo', ésta pueda pararse y dar un mensaje de error, o bien de felicitación al acabar en caso contrario.
Se trata de un musicograma muy simple, pero la dinámica es válida para cualquiera otra que queramos realizar, cambiando solamente los elementos gráficos y decorativos, o aumentando el número de acciones (letra que aparezca tipo karaoke, etc) Es posible que haya formas más eficaces de hacerla, en cuyo caso sería de agradecer que se postearan.

Esquema general
En esencia, lo que queremos conseguir es  reproducir una canción y que, en determinados instantes de esta reproducción, aparezcan elementos gráficos en la escena. Por tanto, tendremos que introducir en la escena un archivo de sonido con sus correspondientes botones de reproducción, y definir unas funciones que se ejecuten cuando el archivo de sonido pase por determinados tiempos.

Paso 1 Preparando elementos de la escena.
Como se puede ver, ésta consta simplemente del título, la letra de la canción y 16 dibujos de corazones que representan el pulso musical y que deben ir apareciendo a tiempo conforme la música va sonando. Estos son instancias de un símbolo y les hemos puesto nombres de instancia c1, c2....c16

Paso 2 Vinculando la música y diseñando el reproductor

Este paso está explicado en el post anterior a este. Repasando, los pasos, rápidamente, son los siguientes:

1) Importamos el sonido wav de la canción a la biblioteca

2) Sobre el sonido importado en la biblioteca, con el botón derecho del ratón seleccionamos 'vinculación' y rellenamos las opciones de vinculación.

3) Añadimos una capa, la llamamos 'acciones' y escribimos el código siguiente 

//VINCULANDO  WAV
musica1 = "XimoBoticari.wav"; //asignamos una variable al wav vinculado
sonidoCancion = new Sound(); //creamos un objeto de sonido
sonidoCancion.attachSound(musica1);// relacionamos ese objeto con la variable del wav

Ahora tenemos un objeto de sonido, 'sonidoCancion' que podemos manejar con ActionScript

 

4) Botones Play/Pause y Stop
Vamos a crear ahora tres nuevas capas, que llamaremos play, pause y stop. En cada una de ellas vamos a arrastrar desde Ventana/Biblioteca/Bibliotecas comunes los botones prefabricados que nos proporciona el propio programa. Aquí se han utilizado los disponibles en la carpeta 'Playback'

Como el botón 'play' debe alternarse con el 'pause', colocaremos ambos superpuestos (pero en capas distintas). El botón 'stop' quedará a la izquierda de ambos. En la siguiente imagen, el botón 'pause' no se ve ya que queda oculto por el 'play', situado en una capa superior.

Funcionará de la siguiente forma: al hacer clic en 'play', comenzará a reproducirse la música, y al tiempo este botón se hará invisible, lo que mostrará el botón 'pause' que hay debajo.

Hacer clic en 'pause' detendrá la canción y almacenará en una variable el tiempo en que se ha detenido. Además, hará nuevamente visible el botón play. Si ahora hacemos de nuevo clicen play, la reproducción comenzará en el tiempo almacenado en la variable.

El botón 'stop' detiene del todo la reproducción y pone todo en las condiciones de inicio.

Por último daremos a los botones los nombres de instancia btn_play, btn_pause y btn_stop respectivamente.

5) Código de acciones de los botones play, pause y stop
Volvemos a la capa acciones y escribimos el código siguiente

//Definimos una variable que almacenará el punto de la canción (en milisegundos)en que nos encontramos.

//Su valor inicial será 0 (inicio de la canción);

var pausa:Number = 0;

//+++++++++++++++++++++++++++

//ACCIONES DEL BOTON 'PLAY' al soltar el boton del ratón

btn_play.onRelease =function(){

//la canción comienza a sonar desde el principio la primera vez o desde el segundo en que se ha hecho pause,

sonidoCancion.start(pausa / 1000);

// La canción está sonando así que hacemos que el botón play se vuelva invisible y el pause visible.

this._visible = 0; 

btn_pause._visible = 1;

};

//++++++++++++++++++++++++++++

//ACCIONES DEL BOTON PAUSE al soltar el boton del ratón

btn_pause.onRelease =function(){ 

//almacena la posición de la canción en el momento de hacer pause 

pausa = sonidoCancion.position; 

//detiene la reproducción 

sonidoCancion.stop(); 

//A la inversa que con play. El botón pause se hace invisible y el play visible 

this._visible = 0; 

btn_play._visible = 1;

};

//++++++++++++++++++

//ACCIONES DEL BOTON 'STOP'

btn_stop.onRelease = function(){ 

//detiene la reproducción 

sonidoCancion.stop(); 

//pone la variable 'pausa' a 0; 

pausa = 0; 

//hace visible el boton play e invisible el pause 

btn_play._visible = 1; 

btn_pause._visible = 0;

};

Paso 3 Determinando los tiempos relevantes de la canción

Esta es la fase más engorrosa de todo el proceso, ya que hay que hacer una lista con los tiempos en  milisegundos en que se producen los eventos que nos interesan.

Abrimos el archivo de sonido con Audacity

Una manera rápida de proceder es averiguar el tiempo en que se inicia el primer compás de la melodía y el tiempo correspondiente al inicio del noveno compás. Si la música está interpretada con un tempo exacto, dividiendo por 16 (ya que estamos en un compás de 2/4) tendremos la duración de cada pulso. De ahí podemos sacar las cifras qe nos interesan.

Por ejemplo, en este caso, la melodia se inicia en t1= 5.960 milisegundos (ms). y el compás noveno se inicia en t17= 17.240 ms. Por tanto la duración de cada pulso será 705 ms.

Podemos hacer más rápido el proceso utilizando una tabla de hoja de cálculo. Así, obtendremos los tiempos en que los dibujos deben aparecer, de acuerdo con el pulso de la canción:

Con esos datos vamos a pegar, en la capa 'acciones', un array que contendrá los tiempos en que se inicia cada pulsación y debe aparecer cada simbolo:

Pegamos en la capa 'acciones':

//Array que contiene los tiempos de cada pulso musical de la melodía

tiempoCancion = new Array(0, 5960, 6665, 7370, 8075, 8780, 9485, 10190, 10895, 11600, 12305, 13010, 13715, 14420, 15125, 15830, 16535, 17240);

Paso 4 El momento del código

El código con el que vamos a conseguir que la reproducción active los símbolos es el siguiente:

Empezamos haciendo todos los corazones invisibles: Introducimos este código en la capa 'acciones'

//++++++++++++++++++++++++++++++

corazones = new Array(0, "c1", "c2", "c3", "c4", "c5", "c6", "c7", "c8", "c9", "c10", "c11", "c12", "c13", "c14", "c15", "c16", "c17");

for (a = 0; a < 20; a++)

{

_root[corazones[a]]._visible = 0;

}

//+++++++++++++++++++++++++++++++

Ahora vamos a definir una función, 'mostrarPulsación', que irá haciendo visibles los corazones cuando la canción pase por los tiempos definidos en el array 'tiempoCanción'

//++++++++++++++++++++++++++++++++

function mostrarPulsacion()

{

if ((sonidoCancion.position > tiempoCancion[n]) && (sonidoCancion.position < tiempoCancion[n + 1]))

{

_root[corazones[n]]._visible = 1;

}

//cuando la canción rebasa l           

if ((sonidoCancion.position > tiempoCancion[n + 1]) && (sonidoCancion.position < tiempoCancion[n + 2]))

{

n++;

}

}

//++++++++++++++++++++++++++++++++++

Veamos el código con detenimiento:

sonidoCancion.position devuelve el tiempo en milisegundos conforme la canción se va reproduciendo. La primera condición if detecta si la canción se encuentra entre los valores n y n+1. En ese caso hace visible el corazón 'n' .

La segunda condición if aumenta el valor de 'n', con lo que el proceso vuelve a repetirse nuevamente, y así sucesivamente.

Solo falta ahora introducir, en el boton 'play', dos cosas. Una es que se ejecute esta función,  mostrarPulsacion.

La otra es introducir una funcion setInterval, que llamaremos 'refresco' para que se compruebe continuamente el paso del tiempo. Así, el boton 'play' quedará así:

//++++++++++++++++++++++++++++++++++++++++++

btn_play.onRelease = function()

{

//la canción comienza a sonar desde el principio la primera vez o desde el segundo en que se ha hecho pause,

sonidoCancion.start(pausa / 1000);

//se ejecuta la función 'mostrarPulsacion'

mostrarPulsacion();

//definimos un setInterval que compruebe como está todo cada 20 ms

refresco = setInterval(mostrarPulsacion, 20);

// La canción está sonando así que hacemos que el botón play se vuelva invisible y el pause visible.

this._visible = 0;

btn_pause._visible = 1;

};

//+++++++++++++++++++++++++++++++++++++++++

[Nani]

Aquí va mi primer musicograma, por si a alguien le sirve.

Tanabata

[josep painous escofet]

Li ensenyaré al Profe de música de l'escola.

Gràcies pel treball

 

[Octavi Soler]

Gracias Roger.

Convertirlo en generador me temo que se sale de mis conocimientos. Lo que si es posible porque lo he probado es que el texto aparezca estilo 'karaoke'  utilizando cuadros de texto dinámicos y arrays conteniendo las sílabas. Sin embargo, no estoy tan seguro de la utilidad pedagógica de esta característica. De hecho, los alumnos cantan y expresan mucho mejor si el aprendizaje de la canción se hace por imitación vocal que cuando se apoya en texto escrito y yo empiezo siempre los aprendizajes de manera exclusivamente oral. Y lo que estoy estudiando y no tengo resuelto aún es hacer que el alumno pueda seguir el musicograma sobre la PDI. Si señala las pulsaciones fuera de tempo (dando una tolerancia, claro) debería salirle un mensaje de error. En caso contrario, una felicitación al finalizar la canción.

Saludos y felicitaciones por tu magnífica labor.

 

[roger]

Un buen trabajo Octavi. Sería interesante poder convertirlo en generador y que simplemente escribiendo un texto en un fichero y el intervalo. No se si realmente se podría ajustar el espacio al texto. Lo que sí se podría hacer es que saliera la palabras o conjuntos de palabras en intervalos programados pero esto sería ya otra cosa.

[Nani]

GRACIASSSSSSSSSS